[Moyen] Simuler une téléportation de PNJ

; Script permettant de simuler la téléportation d'un PNJ vers un autre lieu.
; Dans l'exemple, le sort nen_teleport_spell est un simple sort de lumière (on ne s'en sert que pour avoir l'effet visuel sur le PNJ).
; La référence "mon_marker" est la référence d'un marqueur vers lequel on veut téléporter l'acteur scripté.


Scn nen_pseudoteleport_script


short begin_teleport ; Indique l'état de la téléportation
float timer ; Compteur de temps
Ref moi_meme ; Référence de l'acteur scripté


Begin OnActivate
   if ( begin_teleport == 0 ) ; Empêche d'activer l'acteur pendant qu'il se téléporte
      Activate
   endif
End


Begin GameMode
   if ( begin_teleport == 0 ) ; Tant que l'acteur ne doit pas se téléporter...
      Return ; ... on ne fait rien.
   endif
   if ( GetDead == 1 ) ; Si l'acteur est mort en cours de téléportation...
      Set begin_teleport to 0 ; ... on réinitialise la variable begin_teleport pour éviter de rappeler la fonction GetDead à chaque frame (légèrement plus efficace)
      Return ; ... et on ne fait rien d'autre.
   endif

   if ( begin_teleport == 3 )
      MoveTo mon_marker ; On déplace effectivement l'acteur scripté jusqu'au marqueur qui nous intéresse...
      Set begin_teleport to 0 ; ... et on indique que la téléportation est terminée
      Return ; Evite de tester les conditions en dessous.
   endif

   if ( begin_teleport == 2 ) ; Après que l'acteur scripté se soit lancé le sort bidon, on attend un peu pour que l'effet visuel se termine.
      Set timer to ( timer + GetSecondsPassed ) ; Compteur de secondes écoulées
      if ( timer > 2 ) ; Passé deux secondes...
         Set timer to 0 ; ... on réinitialise le timer...
         Set begin_teleport to 3 ; ... et on indique que l'effet visuel s'est terminé.
      endif
      Return ; Evite de tester les conditions en dessous.
   endif

   if ( begin_teleport == 1 ) ; Si on doit lancer la téléportation...
      Set moi_meme to GetSelf ; ... on obtient la référence de l'acteur scripté...
      Cast nen_teleport_spell moi_meme ; ... on lui fait lancer un sort bidon sur lui même juste pour l'effet visuel...
      Set begin_teleport to 2 ; ... et on indique que cette étape a été faite.
   endif
End